! -----------------------------------------------------------------------------
! PARANOIA -- a solo paranoia game taken from the Jan/Feb issue (77) of
! "SpaceGamer/FantasyGamer" magazine.
!
! Article by Sam Shirley.
!
! Implemented in C on Vax 11/780 under UNIX by Tim Lister.
!
! Converted to Inform 6 by Glenn Hutchings.
!
! This is a public domain adventure and may not be sold for profit.
! -----------------------------------------------------------------------------

Switches dxv5;

Constant Story	  "PARANOIA";
Constant Headline "^Un futur pas-très-interactif
		   ^
		   ^D'après un article par Sam Shirley
		   ^Implementé en C sur un Vax 11/780 par Tim Lister
		   ^Converti en Inform par Glenn Hutchings (zondo@@64hunting2.demon.co.uk)
		   ^Traduit en Français par Gorecki Sabine (http://fa1ckg.free.fr/phpbb)
		   ^Tapez 'aide' pour avoir la liste des commandes.
		   ^
		   ^";
Serial   "990528";
Release  1;

Replace DrawStatusLine;

Include "Parser";

Object	LibraryMessages "lm"
  with	before [;
		Miscellany:
			switch (lm_n) {
			3:	"Vous avez perdu";
			10:	"Tapez une commande, Philo.";
			}
		Score: ;
	];

Include "VerbLib";

Constant MOXIE		= 13;
Constant AGILITY	= 15;
Constant MAXKILL	= 7;
Constant MAXCLONE	= 6;

Global clone		= 1;
Global computer_request = 0;
Global ultra_violet	= 0;
Global action_doll	= 0;
Global hit_points	= 10;
Global read_letter	= 0;
Global plato_clone	= 3;
Global blast_door	= 0;
Global killer_count	= 0;
Global moan_count	= 0;
Global moan_turn	= -1;

Global option;

! -------------------------------- Functions ----------------------------------

[ Initialise;
	print "^^Bienvenue à Paranoia!";

	print "^^"; style bold; print "COMMENT JOUER"; style roman;

	print "^^De temps en temps dans cette aventure, on vous donnera
	       des choix de choses à faire. Choisissez toujours l'option
	       la moins dangereuse. Continuez à faire cela jusqu'à ce que vous gagniez. De temps en temps
	       vous utiliserez une compétence ou vous engagerez dans un combat et serez informé
	       du résultat. Ces sections seront évidentes. Voici quelques autres commandes
	       que vous pouvez utiliser -- tapez 'aide' pour vous y référer.";

	print "^^"; style bold; print "COMMENT MOURIR"; style roman;

	print "^^Comme Philo-R-DMD, vous mourrez plusieurs fois pendant l'aventure.
	       Un nouveau clone sera activé pour prendre la place de celui qui est
	       mort, dans un emplacement différent. Le nouveau Philo-R
	       devra normalement retracer le chemin du vieu Philo-R;
	       Avec l'espoir qu'il ne fera pas les mêmes erreurs que son prédécesseur.";

	print "^^"; style bold; print "COMMENT GAGNER"; style roman;

	print "^^Simplement en achevant la mission avant de dépenser vos six clones.
	       Souvenez vous... restez en alerte, et tenez votre laser qui vous sera utile.";

	print "^^";
	location = page_1;
];

! Print game info.
[ InfoSub;
	print "Merci pour votre demande, Philo. Accès
	       aux archives...";

	print "^^PARANOIA est basé d'après une aventure solo de Sam Shirley
	       publication Jan/Feb 1977 du  magazine ~SpaceGamer/FantasyGamer~,
	       Qui est à son tour basé sur le jeu de rôle Paranoia.  Il a été
	       implémenté en C sur un Vax 11/780 par Tim Lister, qui est la source
	       que j'ai prise. Juste pour m'amuser (et pratiquer la programmation)
	       je l'ai transcrit en language Inform.";

	print "^^Note pour tous les fans de IF: Ce n'est pas très interactif. Il
	       n'est pas approprié au jeu IF. Il bat l'analyseur syntaxique
	       d'Inform dans une sombre allée. Mais il vous fera plus apprécier
	       tous les autres jeu IF.";

	new_line;
];

! Print your character's stats (not that they'll make any difference 8-).
[ StatsSub;
	print "^                       	Personnage Philo-R-DMD-", clone, "^";
	print "^Premier Attribut                                Second Attributs
	       ^==========================================================================================
	       ^Force ........................ 13                  Capacité Transport ....................... 30
	       ^Endurance ................. 13                  Dégats Bonus .................................. 0
	       ^Agilité ...................... 15                  Macho Bonus ................................ -1
	       ^Dexterité Manuelle ... 15                  Mélée Bonus ............................... +5%
	       ^Moxie ........................ 13                  Visée Arme Bonus .................... +10%
	       ^Culot ........................... 8                  Compréhension Bonus ................. +4%
	       ^Aptitude Mécanique ... 14                  Plausibilité Bonus .......................... +5%
	       ^Index Puissance ......... 10                  Réparation Bonus ........................ +5%
	       ^==========================================================================================
	       ^Crédits: 160                                        Secrêt Société: Illuminati                                      Secrêt Société Rang: 1
	       ^Groupe Service: Puissance Services     Mutant Puissance: Précognition^
	       ^Arme: pistolet laser; frappe, 40%; type, L; Gamme, 50m; Recharge, 6r; Malfnt, 00.
	       ^Compétence: Basique 1(20%), Visée Arme Combat 2(35%), Intimidation 3(34%).
	       ^Développement Personnel 1(20%), Communications 2(29%), Laser 3(40%).^
	       ^Equipement: Armure Rouge Réflec, Pistolet Laser, Baril Laser (rouge),
	       ^                   Calepin & Stylo, Couteau, Com Unit 1, Combinaison de saut,
	       ^                   Oeil Secrêt Illuminati-Dans-La-Pyramide(tm) Anneau Décodeur,
	       ^                   Ceinture Utilitaire & Poches.^";
];

[ MoanSub;
	if (moan_turn < turns - 1) moan_count = 0;
	moan_turn = turns;

	switch (++moan_count) {
		1: "C'est une commande non autorisé, Philo.";
		2: "C'est une autre commande non autorisée, Philo.";
		3: "C'est encore une autre commande non autorisée. êtes vous
		    a la hauteur de cette mission, Philo? Vous pouvez me le dire.
		    L'ordinateur est votre ami.";
		4: "Encore une autre commande non autorisée! Je commence a
		    suspecter que vous êtes un traitre de mutant qui a
		    l'intention de saboter l'ordinateur.";
		5: print "Vous entendez une voix forte métallique. ~Attention!
			  sabotage d'ordinateur en cours!~ Avant que vous ne puissiez
			  même taper ~annuler~, 13 kilbots partent de tous les côtés
			  et vous détruisent en milliers de particules.";
		   NewClone();
		   new_line;
		   PlayerTo(page_1);
	}
];

[ HelpSub;
	print "Merci d'avoir sélectionné l'option d'aide, Philo.
	       Voici une liste des commandes que vous êtes autorisés a utiliser.^
               ^      1, 2, ...            Sélection d'une option appropriée
               ^      continue (ou c)      Continue votre mission
               ^      regarder (ou r)      regarder autour de vous
               ^      stats (ou s)         Montre vos statistiques
               ^      info (ou i)          Imprime l'info sur le jeu
               ^      aide (ou h)          Montre ce message d'aide
               ^      sauver               Sauvegarde votre jeu
               ^      charger              Charge un jeu sauvegardé
               ^      recommencer          Recommence le jeu
               ^      version              Montre la version du jeu
               ^      script               Commence une transcription de jeu
               ^      unscript             Fin de la transcription
               ^      debug                Hack  debugger dans le jeu
               ^      quitter (ou q)       Quitte le jeu
	       ^^Si vous avez des questions sur chacune des commandes,
	       S'il vous plaît n'hésitez pas a me demander. L'ordinateur
	       est votre ami.^";
];

! Fiendish computer trap. (Piege d'ordinateur diabolique.)
[ TrapSub;
	print "~Félicitation, Philo. Vous avez avec succès
	       activé la  commande secrète  Debugging Auto-Incrimination,
	       et découvert encore un traitre de mutant.~^^Tandis que vous
	       êtes étonné et vous demandez a qui l'ordinateur se réfère,
	       Des lasers cachés jouent avec vous et vous taillent des trous pas
	       commodes, comme un vulgaire pain de gruyère.";
	NewClone();
	new_line;
	PlayerTo(page_1);
];

! Standard magic words.
[ XyzzySub;
	print "Une voix creuse dit";
	if (ultra_violet == 0)
		"~C'est SEULEMENT une commande A-1 ULTRAVIOLET~.";
	print "~ULTRAVIOLET AUTORISATION VERIFIE~. Une électrode géante descend
	       du plafond et vous êtes engluti dans un bleu pâle
	       rayon dématérialisation.^^Vous apparaissez dans ce qui ressemble a
	       un labyrinthe de petits passages tortueux, tout semblable. en regardant
	       autour, Vous remarquez un petit nain dans la pièce.
	       Il semble être en train de lancer une hache dans votre dos.^^BRUIT SOURD!";
	NewClone();
	new_line;
	PlayerTo(page_1);
];

! Roll a few dice and return the result. (Rouler quelques des et rendre le resultat.)
[ DiceRoll number faces i total;
	total = 0;

	for (i = 0: i < number: i++) {
		total = total + random(faces);
	}

	return total;
];

! Oops -- clone just died. Start a new one. (Oops - le clone est juste mort. Commencer un nouveau.)
[ NewClone;
	print "^^Clone ", clone, " juste mort.";

	if (++clone > MAXCLONE) {
		print "^^Oh mon cher. Vous semblez avoir utilisez tous vos clones.";
		deadflag = 1;
	} else {
		print "^^Clone ", clone, " bien activé.";
		ultra_violet = 0;
		action_doll = 0;
		hit_points = 10;
		killer_count = 0;
		moan_count = 0;
	}
];

! Brutally hack the input line before the parser gets hold of it.
! Taillez brutalement la ligne d'entree avant que l'analyseur syntaxique ne s'en saisisse.
[ BeforeParsing;
	! Only one word allowed. (Seulement un mot permis.)
	parse->1 = 1;

	! Try an option number first.(Essayez une option numeroter d'abord.)
	option = TryNumber(1);
	if (option ~= -1000) {
		parse-->1 = 'opt';
		return;
	}

	! If not, recognize other special commands. (Si pas, reconnaissez d'autres commandes speciales.)
	switch (NextWord()) {
		! Single-letter commands. (Commandes de lettre simple marquepage1.)
		#n$c:		parse-->1 = 'cont';
		#n$h:		parse-->1 = 'aide';
		#n$i:		parse-->1 = 'info';
		#n$r:		parse-->1 = 'regarder';
		#n$q:		parse-->1 = 'quitter';
		#n$s:		parse-->1 = 'stat';

		! Long versions of same. (longues versions de meme.)
		'continue':	parse-->1 = 'cont';
		'aide':		parse-->1 = 'aide';
		'regarder':		parse-->1 = 'regarder';
		'quitter':		parse-->1 = 'quitter';
		'stats':	parse-->1 = 'stat';
		'info':		parse-->1 = 'info';
		'debug':	parse-->1 = 'debug';
		'xyzzy':	parse-->1 = 'xyzzy';
		'plugh':	parse-->1 = 'xyzzy';

		! Let a few standard commands through. (Laissez quelques commandes standard.)
		'sauver':	break;
		'charger':	break;
		'recommencer':	break;
		'version':	break;
		'script':	break;
		'unscript':	break;

		! Otherwise, just moan. (Autrement, juste moan.)
		default:	parse-->1 = 'moan';
	}
];

! Select a location option.
[ Pick prop loc zr;
	loc = location.prop;
	zr = ZRegion(loc);

	if (zr == 2) {
		loc = RunRoutines(location, prop);
		zr = ZRegion(loc);
	}

	if (zr == 1) {
		PlayerTo(loc);
		rtrue;
	}

	if (zr == 3)
		print_ret (string) loc;
];

[ OptionSub;
	switch (option) {
		1: Pick(pick1);
		2: Pick(pick2);
		3: Pick(pick3);
		default: MoanSub();
	}
];

[ ContinueSub; Pick(next); ];

! Custom status line showing no. of clones left. (Ligne de statut personnalisee montrant non. De clone est parti.)
[ DrawStatusLine width posa posb;
	@split_window 1; @set_window 1; @set_cursor 1 1; style reverse;
	width = 0->33; posa = width-26; posb = width-13;
	spaces width;
	@set_cursor 1 2; print (name) location;

	if (width > 76) {
		@set_cursor 1 posa; print "Clone: ", clone;
		@set_cursor 1 posb; print (string) MOVES__TX, turns;
	}

	if (width > 63 && width <= 76) {
		@set_cursor 1 posb; print clone, "/", turns;
	}

	@set_cursor 1 1; style roman; @set_window 0;
];

! ---------------------------- Grammar extensions marquepage2-----------------------------

Include "FrenchGglulx";

Verb	"opt"	*	-> Option;
Verb	"cont"	*	-> Continue;
Verb	"stat"	*	-> Stats;
Verb	"moan"	*	-> Moan;
Verb	"info"	*	-> Info;
Verb	"debug"	*	-> Trap;
Verb	"aide"	*	-> Help;
Verb	"xyzzy" *	-> Xyzzy;

! ------------------------------- The Node Class ------------------------------

! This class implements the basic adventure 'page', a Node. Each node is
! just a location with a few special properties.
! Cette classe execute un Noeud de l'aventure de base 'la page'. Chaque noeud est
! juste un emplacement avec quelques proprietes speciales.

Property text;		! Text printed when the node is visited. (Le texte imprime quand le noeud est visite.)
Property run;		! Routine run after the text is printed. (La routine est lance apres que le texte soit imprime.)
Property next;		! Next node in sequence (if no options specified).(Noeud suivant dans l'ordre (si aucune option indiquer).)

Property opt1;		! Option text (or a routine to return it). (Texte d'option (ou une routine pour le rendre).)
Property opt2;		! Only 3 options catered for at the moment, (Seulement 3 options desservies pour l'heure actuelle,
Property opt3;		! although it can be increased easily. bien qu'il puisse etre augmente facilement.)

! Noeuds atteints en choisissant l'option appropriee,
! ou une routine pour le rendre. Il doit y avoir le
! Le meme nombre d'appuis verticaux 'de 'pick' que 'opt'.

Property pick1;		! Nodes reached by choosing the appropriate option,
Property pick2;		! or a routine to return it. There should be the
Property pick3;		! same number of 'pick' props as 'opt' ones.

Class	Node
	with describe [;
		switch (ZRegion(self.text)) {
			2: self.text();
			3: print (string) self.text;
		}

		if (self provides run) self.run();

		self.numopts = 0;
		self.showopt(1, opt1);
		self.showopt(2, opt2);
		self.showopt(3, opt3);
		if (self.numopts > 0) return;

		if (self provides next && deadflag == 0)
			"^^Tapez ~c~ pour continuer la mission.";
		"^^[ Il n'y a pas d'échapatoire de ce node. ]";
	],
	showopt [ n prop str;
		if (~~(self provides prop)) rfalse;
		str = self.prop;
		if (ZRegion(str) == 2) str = self.prop();
		if (str == 0) rfalse;
		if (self.numopts++ == 0) print "^^";
		print "  (", n, ") ", (string) str, "^";
	],
	numopts 0,
	text "[ Pas de description écrite pour ce node. ]",
	pick1 [; MoanSub(); ],
	pick2 [; MoanSub(); ],
	pick3 [; MoanSub(); ],
	next  [; MoanSub(); ],
  has	light;

! --------------------------------- The Game ----------------------------------

Node	page_1 "Salle de Réunion"
with	text   "Vous vous réveillez défiant du regard le rouge et rose du carrelage sur le sol,
                et vérifiez le E-Z-Kleen. Vous reconnaissez le modèle, c'est le type
		préféré de la sécurité interne de la salle de réunion. Quand vous
		regardez finalement autour de vous, vous voyez que vous êtes seul dans la
		large salle de réunion pour les missions.",
	next	page_57;
! marquepage3
Node	page_2 "Station Réquisitoire"
with	text   "~Salutations,~ dit la Sécurité Interne réquisitoire avec bonté
		qui vous rencontre a la porte, ~Qu'allons nous faire aujourd'hui?~
		Il vous offre un beignet et un café et demande ce qui vous amène ici.
		Cela ne semble pas si mauvais, ainsi vous lui dites que vous êtes venus
		pour lui avouer quelque possible écarts dans la sécurité.
		Il sourit sciemment, attrapant adroitement votre café tandis que vous
		vous éffondrez sur le sol. ~Rien d'alarmant;
		c'est juste un serum de vérité,~ il dit, vous trainant derrière dans
		la salle de discussion.^^Les cinq autres heures suivantes sont dans le
		brouillard, mais vous pouvez vous rappeler quelques fragments de conversation
		de votre société secrète, Votre puissance de mutant, et votre méfiance
		quelque peu paranoiaque de l'ordinateur.  Cela dois expliquer pourquoi vous
		êtes un goinfre vous déplaçant lentement en bas de la chaine alimentaire
		vers les Services d'abattoirs.",
	run [;
		NewClone();
	],
	next [;
		if (computer_request == 1) return page_45;
		return page_32;
	];

Node	page_3 "Terminal"
with	text   "Vous marchez au plus proche terminal et demandez plus
		d'information au sujet de noel.  L'ordinateur dit, ~C'est
		SEULEMENT un A-1 ULTRAVIOLET TERMINAISON IMMEDIATE sujet confidentiel.
		Quelle est votre autorisation s'il vous plait, Philo?~",
	opt1	"vous donnez votre autorisation correctement.",
	pick1	page_4,
	opt2	"Vous mentez et revendiquez l'autorisation Ultra-violet.",
	pick2	page_5;

Node	page_4 "Terminal"
with	text   "~C'est une information classée, Philo, merci
		Pour votre enquête. S'il vous plait faite un rapport a la Sécurité
		Interne de la station réquisitoire aussitôt que possible.~",
	next	page_9;

Node	page_5 "Terminal"
with	text   "L'ordinateur dit, ~Philo, vous ne portez pas la
		couleur d'uniforme correcte.  Vous devez mettre un uniforme
		Ultra-violet immédiatement.  Je me suis occupé de tous et j'en
		ai commandé une déja; il sera là bientôt.  Attendez s'il vous plait
		le dos au mur jusqu'a ce qu'il arrive.~  En moins d'une minute un infrarouge
		arrive portant un paquet blanc.  Il vous demande de signer pour cela, vous le
		remet ensuite et reste derrière, Bien a l'exterieur du rayon de la
		détonation d'une grenade de fragmentation.",
	opt1	"Vous ouvrez le paquet et mettez l'uniforme.",
	pick1	page_6,
	opt2	"Vous reprenez finalement connaissance et vous vous enfuyez.",
	pick2	page_7;
!marquepage4
Node	page_6 "Terminal"
with	text   "L'uniforme vous fait paraitre prompt et astucieux.  C'est
		vraiment impressionnant, et il a même le nouveau revers
		que vous admirez tant.  Qui plus est, les citoyens de tous
		les rangs pourraient venir avec une attention flatteuse.
		Ce n'est pas si mal d'etre un Ultra-violet.
		Vous pourriez probablement finir par aimer cela.^^Un beep émis par
		l'ordinateur interrompt vos songerie.",
	run [;
		ultra_violet = 1;
	],
	next	page_8;

Node	page_7 "Terminal"
with	text   "Le couloir faiblement éclairé est tout à coup illuminé par des
		lumières rouges et des sirènes retentissent tout autour de vous pour
		signaler une intrusion au service de securité.
		Vous courrez tête baissée dans le couloir et tournez désespérement 
		dans un autre couloir au hasard, vous entrez seulement en collision avec une
		équipe de patrouille de 12 Bleu de soldats.
		~Stop, Face de rat,~ crie le commandant, ~ou il n'y aura pas assez de ta
		carcasse pour mon arme.~ ~Allez, soldats, foutez moi cet investigateur dans cet
		uniforme, ~ ordonne t'il, agitant l'extrêmité fin de son laser bleu sous
		votre nez. De son autre main il secoue un paquet blanc ouvert  qui révèle
		un uniforme d'un citoyen primitif Ultra-violet. Un de ses expert de la
		patrouille vous saisit par le cou tel un vautour qui agrippe sa proie de sa
		griffe mortelle ( Vous en avez vu un royal sur le Teela O'Malley dans une
		exposition), Tandis que les autres arrache vos vetements et vous force a
		mettre l'uniforme Ultra-violet. Dès l'instant ou vous êtes habillé
		il se remettent au pas puis au garde à vous.^^~Merci pour votre
		coopération, monsieur,~ dit le leader aux yeux d'acier de la patrouille.
		~Nous allons retourner a nos affaires maintenant.~
		Avec un rythme vif et parfait la patrouille redescend le long
		du couloir. Note: Ne faites pas l'erreur de croire que vos
		compétences s'améliorent à cause de l'uniforme; vous êtes seulement
		expert rouge. Le fait de se faire passer un Ultra-violet déloyalement ne
		doit pas vous faire oubliez cela! Soudainement, un terminal se remet a
		côté de vous.",
	run [;
		ultra_violet = 1;
	],
	next	page_8;

Node	page_8 "Terminal"
with	text   "~Maintenant, à propos de votre question, citoyen.
		La Noel était un vieux stratagème du monde marketing pour inciter
		les citoyens inférieurs à acheter des quantités énormes de
		marchandises, ainsi l'accumulation de grande somme de crédit dans le
		contrôle d'une classe simple de citoyen connu comme détaillants.
		La stratégie utilisée impliquait que tous les bons citoyens donnent
		des cadeaux pendant la Noel, ainsi si on voulait être un membre de valeur
		de société on devait aussi donner des cadeaux pendant la Noel. Plus les
		cadeaux avaient de la valeur plus le citoyen avait de la valeur aussi et
		ainsi faisant, les détaillants venaient pour contrôler la somme
		disproportionnée de la monnaie. De cette façon la Noel a finalement causé
		l'écroulement du vieux monde. Tout naturellement, la Noel a été
		déclaré une pratique perfide dans le Complexe Alpha.
		Merci pour votre enquête.~^^Vous continuez sur votre voie GDH7-beta.",
	next [;
		if (ultra_violet == 0) return page_10;
		return page_10a;
	];
! marquepage5
Node	page_9 "Extérieur De La Station De Réquisitoire"
with	text   "Comme vous marchez vers la navette qui vous prendra à
		GDH7-beta, vous passez devant la Station de Sécurité
		Interne de Réquisitoire ou une lumière d'une brillance
		bleue et orange vous éblouie.
		À l'intérieur, vous pouvez voir un agent IS saluer gaiement
		un citoyen infrarouge et le mener ensuite du bout du fusil dans
		une des salles de discussion.",
	opt1	"Vous décidez de stopper ici et discuter, comme ordonné par
		 l'ordinateur.",
	pick1 [;
		computer_request = 1;
		return page_2;
	],
	opt2	"Vous continuez juste gaiement sur le passage.",
	pick2 [;
		if (ultra_violet == 0) return page_10;
		return page_10a;
	];

Node	page_10 "Complexe Alpha"
with	text   "Vous flânez vivement en bas du couloir à travers
		une passerelle, se balançant dangereusement sous une porte gondolée
		qui a un besoin urgent de réparation, et dans le grand central vous
		pouvez apperçevoir une navette.
		C'est le centre agité de transport du Complexe Alpha.
		Avant que vous ne vous déployez dans le labyrinthe sinueux des
		ascenseurs la navette trace et accélère linéairement.  Vous étudiez
		bravement la carte 3-D particulièrement développée de la route de navettes;

		vous ne seriez pas le premier Expert à prendre une navette rapide.",
	opt1	"Vous décidez de questionner l'ordinateur sur Noel utilisant un
		 terminal voisin.",
	pick1	page_3,
	opt2	"Vous pensez que vous avez mis au point l'itinéraire, donc vous abordez
	une navette.",
	pick2	page_10a;
! marquepage6
Node	page_10a "Navette"
with	text   "Vous sélectionnez nerveusement une navette et montez à bord.",
	next [;
		if (DiceRoll(2, 10) < MOXIE) {
			print "Vous attrappez juste une navette de la ligne pourpre.^";
			return page_13;
		} else {
			print "Vous attrappez juste une navette de la ligne brune.^";
			return page_48;
		}
	];

Node	page_11 "Salle de Réunion"
with	text [;
		print "L'impression sur le papier dit ~Réunion Auto Experimental.~
		Vous l'ouvrez et commencez à lire la chose suivante:^^";
		print "Etape 1: Contraindre l'agent d'investigation à attendre la réunion.^";
		print "^        Note: Voir Information Experimental sous forme Indigo-WY-2, 
		       ^        'Sujet experimental acquisition soumise par
		       ^        l'utilisation de la Neurotoxin salle Foggers.'^^";
		print "Etape 2: Informer l'agent d'investigation que la réunion a commencé.^";
		print "^        ATTENTION: LA RÉUNION COMMENCE.^^";
		print "Etape 3: Présenter le matériel de réunion à l'agent d'investigation.^";
		print "^        SALUTATIONS PHILO.^
		       ^        VOUS AVEZ ÉTÉ SPÉCIALEMENT SÉLECTIONNÉ POUR ANÉANTIR TOUT SEUL
		       ^        LE REPAIRE DES ACTIVITÉS TRAITRES DE NOEL. VOTRE MISSION EST D'ALLER A
		       ^        LA HALLE DE DISTRIBUTION DES MARCHANDISES 7-BETA DE RECENSER ET TROUVER
		       ^        TOUTES LES ACTIVITÉS DE NOEL;
		       ^        VOUS DEVEZ VOUS INFILTRER DANS CES CÉLÉBRATIONS DE NOEL,
		       ^        LOCALISER LEUR LEADER, UN INCONNU MAITRE MARCHAND, ET LE RAPPORTER
		       ^        POUR UN PROCÈS ET UNE EXÉCUTION. MERCI A VOUS. L'ORDINATEUR EST
		       ^        VOTRE AMI.^^";
		print "Etape 4: Signer le formulaire de sortie d'agent d'investigation 
		       pour indiquer qu'il a assisté à la réunion.^";
		print "^        ATTENTION: S'IL VOUS PLAIT SIGNEZ VOTRE FORMULAIRE DE SORTIE DE RÉUNION.^^";
		print "Etape 5: Réunion terminée.^";
		print "^        ATTENTION: LA RÉUNION EST TERMINÉE.^^";

		print "Vous marchez vers la porte et tenez votre formulaire signé
		      jusqu'à la fenêtre en plexiglass. Un garde l'inspecte un instant
		      et tire ensuite en arrière les mégaboulons tenant la porte fermée.
		      Vous êtes maintenant libres pour continuer la mission.";
	],
	opt1	"Vous voulez demander à l'Ordinateur plus d'informations
		 au sujet de la Noel.",
	pick1	page_3,
	opt2	"Vous avez décidé d'aller directement à la Halle de Distribution de
		Marchandises 7-beta.",
	pick2 [;
		if (ultra_violet == 0) return page_10;
		return page_10a;
	];

Node	page_12 "Salle de Réunion"
with	text   "Vous vous approchez de la porte et poussez le bouton où est inscrit
		~poussez pour sortir.~ En quelques secondes un garde avec un regard revêche
		pousse sa face dans la petite fenêtre en plexiglass. Vous pouvez voir sa
		bouche articuler des mots mais vous ne pouvez pas les entendre.
		Vous le regardez fixement  un instant avec des yeux vides avant qu'il
		parle dans un haut parleur sur le côté de la porte.  Quand vous y
		mettez votre oreille vous pouvez à peine l'entendre dire, ~Laissez moi
		voir votre formulaire de sortie de réunion.  Vous n'y arriverez pas sans
		cela.~",
	opt1	"Vous vous asseyez à la table et lisez le paquet Orange.",
	pick1	page_11,
	opt2	"Vous regardez un peu plus fixement autour de la pièce.",
	pick2	page_57;

Node	page_13 "Navette"
with	text   "Vous marchez dans la navette qui brille de ses lumières, 
		en vous demandant pourquoi La forme vous rappelait toujours
		des balles.  La navette démarre et l'instant qui suit vos
		pieds dérape sur le sol glissant gris, et vous scotche
		immobile contre le mur quand la navette s'élance vers GDH7-beta.
		Votre seule consolation est de savoir que cela pourrait être plus
		désagréable, beaucoup plus désagréable.^^Pendant que la navette
		s'arrête, vous pouvez aperçevoir un panneau a travers la fenêtre
		qui indique GDH7-beta.  Avec un peu de pratique vous découvrez que vous
		pouvez ramper a la porte pour ouvrir la clenche.",
	next	page_14;

Node	page_14 "GDH 7-Beta"
with	text   "Vous réussissez à sortir de la navette et regardez autour de vous.
		Vous êtes extrêmement confus, vous n'avez jamais vu une telle
		chose auparavant, un vestibule qui est simultanément à la fois rouge
		et vert.  Si c'est le résultat de Noel alors il est facile de voir
		les maux inhérents dans sa pratique. Vous êtes en plein coeur du
		centre de distribution de grandes marchandises.
		Vous pouvez voir toutes les preuves évidentes de la société
		secrète et la déloyale célébration de Noel; derrière la
		un stand un robot avec la face en caoutchouc vend des jouets
		pendant le jour férié, des montages de couronnes s'accrochent
		a chaque lumière, tandis que caché dans l'ombre il y a un citoyen
		portant un bouquet énorme de fleurs synthétiques rouges .",
	next	page_22;

Node	page_15 "GDH 7-Beta"
with	text   "Vous êtes devant un robot avec un visage au regard étrange, ses deux
		oreilles en caoutchouc pointu en coups de coude sont au-dessous d'un
		chapeau déchiré en lambeaux.  ~Hey monsieur,~ dit-il, ~vous faites tous
		vos achats de noel à la dernière minute? Il me reste quelques trucs ici.
		Vous ne voulez pas manquer le grand jour demain, si vous connaissez un
		moyen. ~Le robot ouvre un sac pour vous montrer une pile de poupées
		investigatrices qui sont un peu effilochées.  Il en sort une d'entre elle.
		~regardez, ce sont des poupées investigatrices, elles sont articulées
		et peuvent faire un tas de choses.  elles ont les bras armés et quand
		vous la serrez, son petit fusil injecte une bombe réaliste au Napalm.
		C'est seulement 50 crédits. Oh ouais, joyeux noel!~",
	opt1	"Vous décidez d'acheter la poupée.",
	pick1	page_16,
	opt2	"Vous tirez sur le robot.",
	pick2	page_17,
	opt3	"Vous ignorez le robot et continuez à chercher dans la halle.",
	pick3	page_22;

Node	page_16 "GDH 7-Beta"
with	text   "La poupée est une bonne affaire pour cinquante crédits; il fera un
		excellent cadeau de Noel pour un de vos amis. Après la vente le
		robot roule au loin. Vous pouvez aussi utiliser la poupée plus tard dans
		un combat. Elle fonctionne comme un fusil tirant au napalm,
		sauf que de temps en temps elle éclatera et soufflera l'utilisateur.
		Mais ne laissez pas cette information vous influencer.",
	next [; action_doll = 1; return page_22; ];

Node	page_17 "GDH 7-Beta"
with	text   "Vous sortez brusquement votre laser et tuez le robot, mais 
		ce dernier a le temps de diriger le jouet vers vous. La pression
		du jouet a le même effet qu'un fusil tirant au napalm mais l'armure
		ne résiste pas à votre laser.",
	run [ i robot_hp;
		for (i = 0: i < 2: i++) {
			if (DiceRoll(1, 100) <= 25) {
				print "^^Vous avez été touché!";
				hit_points = hit_points - DiceRoll(1, 10);
				if (hit_points <= 0) {
					NewClone();
					self.goto = page_45;
					return;
				}
			} else {
				print "^^Il vous a manqué, mais pas de beaucoup!";
			}

			if (DiceRoll(1, 100) <= 40) {
				print "^^Vous avez éliminé le petit bâtard!";
				robot_hp = robot_hp - DiceRoll(2, 10);
				if (robot_hp <= 0) {
					print "^^Vous l'avez dilapidé! Bon coup de feu!";
					print "^^Vous aurez besoin de plus de preuves, donc
					vous recherchez encore dans GDH7-BETA.";
					if (hit_points < 10)
						print " après le GDH 
						       Vous a retapé";
					print ".";
					hit_points = 10;
					return;
				}
			} else {
				print "^^Damné! vous tombez!";
			}
		}

		print "^^Il essaye de tirer de nouveau, mais le jouet explose
		       et se détruit.";
		print "^^Vous aurez besoin de plus de preuves, donc vous
			cherchez encore dans le GDH7-beta";
		if (hit_points < 10)
			print " après le GDH vous tombez";
		print ".";
	],
	goto	page_22,
	next [;

		return self.goto;
	];

Node	page_18 "GDH 7-Beta"
with	text   "Vous marchez au centre du hall, décochant une oeillade comme un
		infrarouge de cuves fraiches de clone. Vous voyez une chose surnaturelle
		et imposante devant vos yeux que vous n'aviez jamais vu auparavant, un ver
		de terre super armé. Une horreur de mutant balourds, 15 pieds au-dessus
		de votre tête. Son squelettique corps est drapé de centaines de bandes
		métalliques (probablement pour nier les effets de quelque puissance de
		mutant insidieux) et la créature entière affreuse est enveloppée
		de mille feux clignotants. C'est à des moments comme cela que vous auriez
		souhaité avoir un peu de formation pour ce travail. Heureusement la
		créature ne tient pas compte de votre présence, mais reste dans sa
		position, comme si elle attendait une sommation de son sombre Maitre.
		^^ VLAN! Soudainement vous êtes frappés par derrière",
	next [;
		if (DiceRoll(2, 10) < AGILITY) return page_19;
		return page_20;
	];
! marquepage 7
Node	page_19 "GDH 7-Beta"
with	text   "Rapidement vous regagnez votre équilibre, faites tourbillonner votre
		laser et tirez sur le citoyen Ultra-violet derrière vous. En un instant
		son coeur saute à votre gorge et une pluie de jouets éffilochés
		tombent à vos pieds. Alors vous vous rendez compte qu'il est en effet
		mort et que vous serez le seul à classer un rapport sur cet incident.
		En plus, il participait à ces achats de Noel déloyaux, autre preuve
		valeureuse pour le service de l'ordinateur!",
	next [;
		killer_count++;
		if (killer_count > MAXKILL - clone) return page_21;
		if (read_letter == 1) return page_22;
		return page_19a;
	];

Node	page_19a "GDH 7-Beta"
with	text   "Vous êtes debout devant le corps d'un citoyen mort Ultra-violet.",
	opt1	"Vous fouillez le corps, tenant un oeil ouvert pour la Sécurite Interne.",
	pick1	page_34,
	opt2	"Vous partez en courant comme le chien lâche que vous êtes.",
	pick2	page_22;
! marquepage en cours
Node	page_20 "GDH 7-Beta"
with	text   "Oh non! Vous n'arrivez pas à garder votre équilibre. Vous tombez
		la tête la première sur la dinde de noel.
		C'est une lutte vaillante; vous pensez que vous aller en finir quand une
		flèche empoisonnée se plante dans votre chair, mais un effort héroique
		Vous tirez brusquement une série de feux dans tous les sens créant un
		embouteillage vivant qui va se loger dans l'épine dorsale de la créature.
		La bête de Noel se renverse à terre et commence à brûler, remplissant
		le secteur d'une fumée épaisse âcre. Elle ne met pas longtemps à
		se décomposer. Maintenant vous êtes prêt à continuer votre
		recherche du Maître Détaillant.",
	next	page_22;

Node	page_21 "GDH 7-Beta"
with	text   "Vous avez fait le tour de tous les citoyens principaux du Complexe Alpha
		à un taux prodigieux. Ce n'est pas passé inaperçu au niveau de l'équipe
		de Sécurité Interne du GDH 7-beta. Soudain, un réseau de rayons laser se
		lance d'un coin sombre du hall, vous faisant exploser en millier de
		particules, vous réduisant en cendre.",
	run [;
		NewClone();
	],
	next	page_45;

Node	page_22 "GDH 7-Beta"
with	text   "Vous recherchez dans le Hall de Distribution de Marchandises 7-beta.",
	next [;
		switch (DiceRoll(1, 4)) {
			1, 2:	return page_18;
			3:	return page_15;
			4:	return page_29;
		}
	];

Node	page_23 "Terminal"
with	text   "Vous allez au plus proche terminal et declarez un mutant. ~Mutant en vue!
		il y a un mutant ici.~  Vous entendez des hurlements innaudibles auparavant
		un infra-rouge parcourt votre épaule. Vous l'abattez facilement, mais une
		douzaine de citoyens tiennent leurs armes visées sur vous.",
	opt1	"Vous leur dites que c'était seulement une mauvaise plaisanterie.",
	pick1	page_28,
	opt2	"Vous voulez les vaincre, un contre douze.",
	pick2	page_24;

Node	page_24 "Terminal"
with	text   "Bomberman, je ne me suis jamais attendu a ce que quelqu'un choisisse
		cette option. Je n'ai donc pas conçu les 12 citoyens qui vont faire une
		éponge de vous. Dites-vous bien que je vous donne néanmoins une seconde
		Chance.",
	opt1	"Vous changez d'avis et dites que c'était seulement une mauvaise plaisanterie.",
	pick1	page_28,
	opt2	"Vous voulez VRAIMENT les tuer.",
	pick2	page_25;

Node	page_25 "Terminal"
with	text   "Mon garçon, vous ne pouvez pas réellement prendre une allusion!
		^^Ca se resserre.
		Leurs doigts se crispent d'un coup sec sur la détente, ils sont sur le point
		de tirer. C'est votre dernière chance.",
	opt1	"Vous leur dites à tous que c'était juste une mauvaise plaisanterie.",
	pick1	page_28,
	opt2	"Vous allez tirer!",
	pick2	page_26;

Node	page_26 "Terminal"
with	text   "Vous pouvez lire le froid, la haine sobre dans leurs yeux, (ils
		n'ont pas vraiment pensé que c'était drôle), ils ressèrent
		le cercle autour de vous. Un d'entre eux pousse un blaster sous votre
		nez, mais cela n'endommage pas autant que le multi-gigawatt carbonium
		alimentation qui explose dans votre petit dos. Vous passez les
		micro-secondes restantes de votre émerveillement de vie à penser que
		vous avez fait une erreur
..",
	run [;
		NewClone();
	],
	next	page_32;

Node	page_27 "Vide"
with	text   "N'existe pas.  Ne peut pas y arriver avec cette version de Terminal.
		 Conçu pour trouver les cheats codes de dé.";

Node	page_28 "Terminal"
with	text   "Ils ne pensent pas que c'est drôle.",
	next	page_26;

Node	page_29 "GDH 7-Beta"
with	text   "~Psst, hey citoyen, venez ici.  Pssfft,~ vous entendez.
		quand Vous regardez fixement autour de vous, vous pouvez voir le contour
		terne d'une silhouette de quelqu'un dans l'ombre. ~J'ai obtenu quelques
		informations sur le Maître Détaillant. psst Ca vous coûtera
		seulement 30 crédits.~",
	opt1	"Vous payez 30 crédits pour les infos.",
	pick1	page_30,
	opt2	"Vous préféreriez le menacer pour avoir les infos.",
	pick2	page_31,
	opt3	"Vous l'ignorez et vous éloignez.",
	pick3	page_22;

Node	page_30 "Extérieur de la porte blindée"
with	text   "Vous marchez dans l'ombres et donnez 30 crédit a l'homme
		~Laissez les juste tomber par terre,~ dit-il
		~Vous êtes à la recherche du Maître Détaillant, pssfft ?
		Je l'ai vu... C'est un homme gras dans une combinaison de saut confuse
		rouge et blanche. On dit que c'est un haut programmeur sans respect pour
		s'approprier de la sécurite. Si vous voulez le rencontrer alors pssfft
		passez derrière moi et entrez par cette porte.~
		^^ Derrière l'homme il y a une porte blindée en titane.
		A son centre il y a un panneau attaché vers vous, seulement vous en avez
		déjà vu auparavant quand vous avez aidé à tester les rockettes
		plasma sur le terrain. (vous pouvez lire facilement l'imprimerie, bien
		qu'elle soit en italiques). Heureusement elle n'est pas trop loin de vous pour
		que vous puissiez lire: ATTENTION!! N'ouvrez pas cette porte ou un malheur
		vous arrivera. L'ouverture de cette porte est une violation du reglement.
		Ne le faites pas. Ce n'est pas du tout une plaisanterie.",
	
	opt1	"Vous utilisez votre pratique de mutant: pré-connaissance en ouverture
		de porte.",
	pick1	page_56,
	opt2	"Vous passez juste la porte.",
	pick2	page_33,
	opt3	"Vous décidez que c'est trop dangereux et vous éloignez.",
	pick3	page_22;

Node	page_31 "GDH 7-Beta"
with	text   "Comme n'importe quel bon expert vous choisissez la décision la moins chère
		et le menacez pour avoir les informations. 
		Par réflexe vous sortez brusquement votre laser et lui collez sous le
		nez. ~vous criez: Dites moi ou sont ces traitres fétards de Noel ! ou ce
		qui pends sous votre nez flétira votre face de rat, yuk yuk yuk!~
		 vous avez l'air menaçant, mais vous remarquez que quelque chose semble faux.
		 Il n'a pas de nez. C'est une sombre réalité, un hologramme
		planté dans le décor et votre laser est collé à travers l'autre côté
		de sa tête.  ~Allez vous payer maintenant?~ dit l'interlocuteur, ~ou allez
		vous pssfft partir comme un idiot?~",
	opt1	"Vous payez 30 crédits.",
	pick1	page_30,
	opt2	"Vous pssfft partez comme un idiot.",
	pick2	page_22;

Node	page_32 "Réunion de Mission"
with	text   "Finalement c'est votre plus grande chance de prouver que vous êtes un bon
		Expert comme votre clone précédent. Vous marchez vivement jusqu'à
		la réunion de mission et prenez les notes personnelles de votre clone
		précedent effectué par le bloc-notes. Après l'examen des notes vous
		savez ce qui doit être fait. Vous prenez la ligne pourpre qui mène aux
		Hall de Distribution de Marchandises 7-beta et commencez à chercher la
		porte blindée.",
	next	page_22;

Node	page_33 "Dans le Baril"
with	text    "Vous sortez les mégaboulons de la porte blindée, puis vous poussez
		ensuite avec une force effrayante. Lentement la porte s'ouvre en grinçant.
		Vous passez bravement par l'ouverture et passez votre tête dans un silo
		de 300 mm 'ultra choc' classe cannon plasma dans le baril.
		C'est sombre dans le baril maintenant, mais juste avant que votre tête
		ne soit coincée vous ne pouvez pas oublier de voir un groupe de
		techniciens qui vous regardent avec inquiétude entrer là.",
	run [;
		blast_door = 1;
	],
	next	[;
		if (ultra_violet == 1) return page_35;
		return page_36;
	];

Node	page_34 "GDH 7-Beta"
with	text   "Vous fouillez le corps et trouvez une enveloppe contenant une lettre, vous
		l'ouvrez et lisez : ~Le projet de la prise de contrôle du cours de
		formation d'expert va bien, Camarade. Une fois que nous aurons formé
		le bourgeois inconscient expert à travailler comme un communiste dupe,
		le renversement du Complexe Alpha sera irrésistible. Mon enquête sur
		le complexe m'a convaincu que personne ne soupçonne une telle chose;
		Bientôt il sera trop tard pour eux de s'opposer à la révolution.
		La seule chose qui pourrait probablement empecher la populaire révolution
		serait que quelqu'un alerte le Terminal de notre plans (par exemple,
		quelques entreprenants Experts pourraient dire au Terminal que les
		communistes ont libéré le cours de formation d'expert et utilisent le
		plan comme un point de saut pour saper la stabilité de tout le
		complexe Alpha), mais comme nous le savons tous les deux, ce ne serait pas
		dans l'interet du capitaliste Experts prolétariat qui est au-dessus de
		leurs propres désirs bourgeois.
		P.S. je dois faire quelques courses pour la noel plus tard aujourd'hui.
		Voudriez-vous que je vous prenne quelque chose? ~ ^^Quand vous reposez
		la note vous êtes surmonté par une étrange sensation de déjà vu
		de nouveau. Vous vous voyez parlant confidentiellement avec le Terminal.
		Le récit de tous le plan des communistes et ensuite la scène change
		et vous vous voyez remettre des récompenses pour avoir empêché
		le complot insidieux communiste de reprendre le complexe.
",
	run [;
		read_letter = 1;
	],
	opt1	"Vous sortez a toute vitesse au plus proche terminal pour exposer la situation.",
	pick1	page_46,
	opt2	"Vous voulez chercher plus de preuves.",
	pick2	page_22;

Node	page_35 "Dans le Baril"
with	text  "~Oh Maître,~ Vous entendez par le baril d'arme à feu, ~Où étiez vous?
		C'est le moment de la grande cérémonie de Noel. 
		Vous devriez vous dépecher et obtenir le costume.
		Le stagiaire pourrait commencer à avoir des soupçons.
		~C'est la deuxième fois qu'aujourd'hui vous êtes obligé de porter
		ce vêtement qui n'est pas de votre choix.
		Il passe comme un éclair le costume devant votre menton, à l'instant
		ou vous entendez un tir qui éclate derrière vous.
		~Oh la la! Qui a laissé la porte ouverte? tirez rapidement encore au
		canon laser, ou nous sommes tous condamnés.~
		^^ ~Trop tard porc de capitaliste, la force de grêve populaire
		révolutionnaire revendique ce coup de canon pour la lutte vaillante du
		prolétariat contre l'oppression. Que faire, vous, laquais des dirigeants
		de chien d'impérialiste. ~ZAP CAPOUT.~
		^^ Juste quand vous pensiez que les choses ne pouvaient pas empirer,
		~Aha, regardez ce que nous avons ici, ils penseront que le Maître
		Détaillant lui-même c'est fait attrapée dans son propre canon. Sa mort
		sera servie comme un symbole de liberté pour tout le Complexe Alpha. Feu
		du canon.~
",
	run [;
		NewClone();
	],
	next	page_32;

Node	page_36 "Dans le Baril"
with	text   "~FELICITATION, Philo, vous avez avec succès trouvé la tanière du
		Maître Détaillant et achevé le cours de formation d'Expert.
		évaluation de mission~ une voix assourdi vous dit par le baril.
		~Nous allons vous sortir la tête du baril du canon de plasma
		'Ultra Choc', puis vous pourrez commencer un séminaire pour reçevoir
		des formations, la première concernera à 100% l'identification précise
		et l'élimination de mutants non enregistrés.
		Si vous avez une objection exprimez-la s'il vous plaît maintenant.~",
	opt1	"Vous appréciez sa courtoisie et exprimez une objection.",
	pick1 [;
		NewClone();
		return page_32;
	],
	opt2	"Après que votre tête soit enlevée du canon, vous décidez de déclarer
		les mutants.",
	pick2	page_23,
	opt3	"Après que votre tête soit enlevée du canon, vous allez à
		l'identification de mutant non enregistree et au Séminaire Elimination.",
	pick3	page_37;

Node	page_37 "Lecture au Hall"
with	text   "~Venez avec moi s'il vous plaît, Philo,~ Dit le technicien en vert
		d'autorisation après qu'il a déplacé votre tête du
		canon. ~Vous avez participé au cours de formation d'expert puisque vous
		êtes descendus de la navette dans GDH7-BETA,~ explique-t-il comme il vous
		mène en bas au couloir. ~la nomination entière de Noel était une
		mission test pour évaluer votre niveau actuel de formation. Vous n'avez
		pas fait si bien. Nous allons commencer au commencement avec l'autre
		étudiant. Oh, nous y voici, mutant identifié et cours d'élimination.~
		Il vous montre un amphithéâtre énorme rempli de places vides.
		Il y a seulement un autre étudiant ici, un Expert près de la rangée
		de devant, jouant avec sa poupée certainement achetée au Hall. ~Trouve ta place et je commencerai.~
		Dit l'instructeur.
",
	next	page_38;

Node	page_38 "Lecture au Hall"
with	text [; print
		"Je suis Plato-B-PHI-", plato_clone, ", Chef de mutant de propagande ici
		dans le cours de formation. Si vous avez des questions de mutants dites le
		moi s'il vous plaît. Aujourd'hui je parlerai de détection de mutant.
		La détection de mutants est très facile. Une, montre simplement à coup
		sûr des signes, tel que la peau verte écailleuse, le troisième bras
		grandissant sur le front, ou d'autres défigurations semblables si communes
		avec leur sorte. Il y a, cependant, quelques spécimens rares cela ne
		montrent aucun signe extérieur de leur trahison. Cela a été le
		problème significatif, si nos chercheurs ont travaillé sur une solution.
		Je voudrais qu'un volontaire évalue cela.
		Un dispositif,~ dit-il, soulevant une arme à feu de rayon en regardant la
		chose. ~C'est un rayon de détection de mutant. Ce petit bouton détecte
		des mutants et ce grand bouton les abasourdit une fois qu'ils sont
		découverts. Qui voudrait se porter volontaire pour un essai?~ 
		L'expert devant a des convulsions plus profondes dans sa chaise.";
	],
	opt1	"Vous êtes volontaire pour le test.",
	pick1	page_39,
	opt2	"Vous vous cachez derrière une chaise en esperant que l'instructeur ne
		vous remarque pas.",
	pick2	page_40;

Node	page_39 "Lecture Hall"
with	text   "Vous vous portez bravement volontaire pour évaluer l'arme à feu de
		détection de mutant. Vous vous levez et descendez les marches et vous
		dirigez vers le podium, passant devant l'autre Expert très soulagé.
		Quand vous arrivez à la hauteur du podium Plato-B-PHI vous remet l'arme
		à feu de détection de mutant et dit: ~pointez l'arme à feu sur cet
		Expert et poussez le petit bouton. Si vous voyez une lumière pourpre,
		abasourdissez le.~ L'occasion d'avérer votre valeur au Terminal, vous
		tirez un rayon de détection de mutant sur l'autre Expert. Une lumière
		brillante pourpre entoure immédiatement son corps. Vous glissez votre
		doigt sur le grand bouton pour l'abasourdir et il tombe se tordant de
		douleur sur le sol. ~Bon tir,~ Dit l'instructeur comme vous lui remettez

		l'arme, ~je vois que vous avez du plaisir pour cela. Ca montre que vous
		avez saisi le cours de détection de mutant et d'élimination.
		Vous pouvez continuer à la classe d'infiltration de société secrête.
		Je m'assurerai que le petit mutant arrive empaqueté pour la classe de
		dissection de mutant dès demain.~
",
	next	page_41;

Node	page_40 "Lecture Hall"
with	text   "Vous lancez un soupir de soulagement quand Plato-B-PHI harcèle l'autre
		Expert. ~Vous ici devant,~ dit l'instructeur indiquant à l'autre Expert,
		~vous ferez un bon volontaire. Venez s'il vous plaît ici.~ l'expert regarde
		autour de lui avec une expression sur son visage qui dit: `qui moi?'
		mais puisqu'il est le seul visible devant l'auditoire il comprend que
		c'est à lui que l'on s'adresse. Il marche en bas vers le podium.
		~Ici, ~ dit Plato-B-PHI, ~pointez le rayon de détection de mutant vers
		l'auditoire. Si il y a n'importe quels mutants là-bas nous le saurons
		bientôt.~ Soudain votre peau est piquée d'une électricite statique et
		une lumière brillante pourpre entoure votre corps. 
		~Ha Ha Ha, il est là, il y en a un,~ dit l'instructeur.
		~abasourdis le avant qu'il ne s'échappe.~
",
	run [;
		while (1) {
			if (DiceRoll(1, 100) <= 30) {
				print "^^Sa décharge vous frappe. Vous vous sentez totalement engourdi.";
				self.goto = page_49;
				return;
			} else {
				print "^^Sa décharge vous a manqué de justesse.";
			}

			if (DiceRoll(1, 100) <= 40) {
				print "^^Le souffle vous effleure juste. Il
				       dépose le rayon de détecteur de mutant.";
				return;
			} else {
				print "^^Vous brûlez et faites un trou dans le podium. Quel étrange
				réaction a sur vous ce rayon de détecteur de mutant.";
			}
		}
	],
	goto	page_50,
	next	[; return self.goto; ];
! marquepage 8
Node	page_41 "Vestibule"
with	text   "Vous déboulez dans le vestibule de la Formation d'Expert
		cherchant votre classe de cours suivante. Devant vous voyez
		un instructeur vous faisant un signe de la main. Quand vous arrivez à
		sa hauteur il vous serre la main et dit, ~Je suis Jung-I-PSY.  Bienvenue
		au séminaire de la société secrête d'infiltration. J'espère vous...~
		Vous n'entendez pas le reste de sa salutation parce que vous êtes trop
		attentionné par sa poignée de main. C'est la chose la plus étrange
		qui n'a jamais été faite à votre main, comme si vous aviez reçu un
		coup de fouet dans vos neurones, le haut de la paume est massé par une
		énergie. Il ne vous prend pas longtemps pour comprendre de quoi il en
		ressort. Vous le sentez secouer brièvement votre main avec
		le secrêt Illuminati poignée de main.
",
	opt1	"Vous répondez par l'expression de code d'Illuminati approprié,
		 ~Ewige Blumenkraft~.",
	pick1	page_42,
	opt2	"Vous ignorez ce contact de société secrête.",
	pick2	page_43;

Node	page_42 "Vestibule"
with	text   "~Aha, Donc vous êtes un membre d'élite de la société secrête Illuminati,~
		dit-il fort, ~c'est le plus intéressant.~ 
		Il se tourne vers la grande classe déjà assise dans la salle
		et dit: ~vous voyez, en utilisant simplement la poignée de main correcte
		vous pouvez identifier un membre de n'importe quelle société secrête.
		Tenez s'il vous plaît vos armes pointées sur lui pendant que j'appelle la garde.",
	opt1	"Vous vous enfuyez.",
	pick1	page_51,
	opt2	"Vous attendez le garde.",
	pick2	page_52;

Node	page_43 "Lecture Hall"
with	text   "Vous êtes assis au cours sur comment reconnaitre et infiltrer des
		sociétés secrêtes, qui est basé surtout sur les poignées de
		main secrêtes. La théorie de base, que vous comprenez au sein de
		votre formation d'Iluminati, est que vous pouvez passer inaperçu dans
		n'importe quel réunion de société secrête avec la poignée de
		main appropriée. Qui plus est, la poignée de main appropriée
		ouvrira des portes plus rapidement qu'un canon de plasma 'ultra choc'.
		Vous êtes certain qu'avec l'information que vous apprenez ici vous serez
		facilement promu au niveau suivant de votre société secrête Illuminati.
		Le cours continue encore pendant trois bonnes heures, pendant lesquelles
		vous avez l'occasion de pratiquer beaucoup de poignées de main différentes.
		Ensuite chacun est invité à suivre la cérémonie de remise des
		diplômes. Avant que vous ne deviez y aller, vous avez un petit moment
		pour parler au Terminal... vous savez, de certains sujets. ",

	opt1	"Vous allez chercher un terminal.",
	pick1	page_44,
	opt2	"Vous allez à la cérémonie de remise des diplômes immédiatement.",
	pick2	page_55;

Node	page_44 "Terminal"
with	text   "Vous descendez dans une partie semi-isolée de la formation complexe de
		cours et activez un terminal.  ~A VOTRE SERVICE~ lisez vous sur l'écran.",
	opt1	"Vous vous enregistrez comme un mutant.",
	pick1	page_23,
	opt2	"Vous changez d'avis et allez à la cérémonie de remise des diplômes.",
	pick2	page_55,
	opt3 [;
		if (read_letter == 0) rfalse;
		"Vous voulez bavarder du communiste.";
	],
	pick3	[;
		if (read_letter == 0) rfalse;
		return page_46;
	];

Node	page_45 "Logement"
with	text   "~Hrank Hrank,~ l'alarme retentit dans votre logement.
		Il y a quelque chose. Vous regardez le moniteur au-dessus de la salle
		de bains et voyez le message que vous avez attendu toutes ces années.
		~ATTENTION PHILO, VOUS ÊTES ACTIVÉ. ANNONCEZ LE S'IL VOUS PLAÎT
		IMMÉDIATEMENT DANS LA PIÈCE NOMINATION DE MISSION A17/GAMMA/LB22.
		MERCI. L'ORDINATEUR EST VOTRE AMI.~  Quand vous arrivez dans la pièce de
		nomination de mission A17-gamma/LB22 vous prenez à votre clone
		précédent tous les biens restants ainsi que le calepin. Vous essayez de
		résoudre les notes énigmatiques de votre prédécesseur, vous
		déchiffrez assez de chose qui vous mène à la station de métro avec
		la navette a GDH 7-beta.",
	next [;
		if (ultra_violet == 0) return page_10;
		return page_10a;
	];

Node	page_46 "Terminal"
with	text   "~Pourquoi vous posez des questions au sujet des communistes, Philo?
		Ce n'est pas dans votre intérêt pour votre survie de continuer de poser
		des questions sur de tels sujets.~ dit le Terminal.",
	opt1	"Vous insistez sur un entretien sur les communistes.",
	pick1	page_53,
	opt2	"Vous changez de sujet.",
	pick2	page_54;

Node	page_47 "Terminal"
with	text   "Le Terminal ordonne à l'escadron entier de terminer le cours de formation
		d'expert. Malheureusement c'est aussi fini pour vous de posseder les
		informations confidentielles. ^^Ne faites pas l'innocent, nous savons tous
		les deux que vous êtes un Illuminatus qui est en soi un acte de trahison.
		^^Ne comptez pas sur moi pour avoir de la sympathie.
",
	run [;
		deadflag = 1;
	];

Node	page_48 "Navette"
with	text   "La navette avance quand vous entrez, vous faisant tomber en arrière
		dans une pile de déchets. Elle tourne vers le haut et vous éjecte dans
		le broyeur d'ordures puis va directement au Complexe Alpha. Une des
		dernières choses que vous voyez est une petite sphère bleue diminuant
		lentement derrière vous. Après votre échec de rapport, vous serez
		considéré mort.",
	run [;
		NewClone();
	],
	next	page_45;

Node	page_49 "Lecture Hall"
with	text   "L'instructeur traîne votre corps inerte dans une cage de spécimen.
		~il fera un bon sujet de dissection de mutant pour la classe de demain.~",
	run [;
		NewClone();
	],
	next	page_32;

Node	page_50 "Lecture Hall"
with	text   "Vous réprimez l'autre Expert et ensuite sagement vous
		decidez de forer quelques trous dans l'instructeur aussi; le seul
		bon témoin est mort. Vous continuez le cours de formation.",
	run [;
		plato_clone++;
	],
	next	page_41;

Node	page_51 "Vestibule"
with	text   "Vous vous enfuyez, mais vous ne courez pas loin. Trois cents armes
		étranges vous transforment en un gel séché de nuage de suie.",
	run [;
		NewClone();
	],
	next	page_32;
! marquepage 10
Node	page_52 "Vestibule"
with	text   "Vous attendez sagement le retour de l'instructeur avec un garde bleu
		chargé de la sécurité interne. Le garde vous mène dans la salle
		de réquisition interne.",
	next	page_2;

Node	page_53 "Terminal"
with	text   "Vous dites au Terminal:",
	opt1	"Le communiste qui c'est infiltré au cours de formation d'expert
		et la ^ menaçante Révolution Populaire.",
	pick1	page_47,
	opt2	"Quelque chose moins dangereux.",
	pick2	page_54;

Node	page_54 "Terminal"
with	text   "~N'essayez pas de changer de sujet, Philo.~ dit le Terminal.~
		c'est un crime sérieux de poser des questions sur le sujet des communistes.
		Vous serez exterminé immédiatement. Merci pour votre enquête.
		L'ordinateur est votre ami.~ 
		Une cage d'acier descends au dessus de vous, vous prenant au piège dans
		le vestibule. Un rayon de projecteur de la console du Terminal vous
		illumine fortement tandis que le haut parleur au-dessus de votre tête
		répète sans cesse: ~Traître, Traître, Traître.~ 
		Ca ne prend pas longtemps à ce que quelques gardes remarquent votre
		situation fâcheuse et viennent vous terminer.",
	run [;
		NewClone();
	],
	next [;
		if (blast_door == 0) return page_45;
		return page_32;
	];

Node	page_55 "Auditorium"
with	text [; print
		"Vous et 300 autres diplômés excités marchez au pas de
		l'amphithéâtre à un grand auditorium pour la réception d'un
		diplôme. L'auditorium est largement décoré des memes couleurs que la
		classe, rouge vif et vert. Des rubans de plastique et de papier drapent les
		murs, tandis que sur un énorme panneau est écrit: ~Félicitations à
		la classe de GDH7-BETA-203.44/A.~ Une fois que chacun a trouvé sa place
		la cérémonie commence.  Jung-I-PSY commence le premier à parler:
		~Félicitation aux étudiants, vous vous en êtes tous sortis avec
		succès  dans le cours de formation d'expert. Ca m'apporte toujours une
		grande fierté d'adresser à la classe un diplôme, mais je sais, et je
		suis sûr que vous l'êtes aussi, car vous êtes maintenant qualifiés
		pour les missions les plus périlleuses que le Terminal peut choisir pour
		vous. On ne doit pas de remerciements au personnel enseignant, mais à
		tous d'entre vous, qui avez persévéré et obtenu un diplôme.
		Bonne chance.~ Alors l'instructeur commence à lire les noms des étudiants
		qui marchent un à un le long de la salle pour reçevoir leurs diplômes.
		Bientôt c'est votre tour: ~Philo-R-DMD, je vous remet le diplôme
		de maître de mutant identificateur et d'infiltrateur de société
		secrête.~ Vous marchez et allez reçevoir votre diplôme  de
		Plato-B-PHI-", plato_clone,", vous retournez ensuite à votre place.
		Un discours suit pour les diplômes suivants qui sont distribués, mais il
		est moins important. Vous êtes libre de retourner a votre baraquement
		pour attendre, maintenant que vous êtes formé et entièrement qualifié,
		pour votre mission suivante. Dans une semaine vous recevrez la facture
		totale du cours de formation détaillée qui est d'un montant de 1,523 crédits.";
	],
	run [;
		deadflag = 2;
	];

Node	page_56 "Exterieur de la porte blindée"
with	text   "Ce sentiment familier étrange de deja-vu vous enveloppe de nouveau.
		Il est dur de dire ce qu'est de l'autre côté de la porte, ça ne semble
		pas être destiné à vous.",
	opt1	"Vous ouvrez la porte et entrez.",
	pick1	page_33,
	opt2	"Vous allez chercher plus d'information.",
	pick2	page_22;

Node	page_57 "Salle de Réunion"
with	text   "Dans le centre de la pièce il y a une simple table et une chaise.
		Il y a un dossier orange au bout de la table, mais vous ne pouvez pas
		discerner ce qui est dessus.",
	opt1	"Vous vous asseyez et lisez le dossier.",
	pick1	page_11,
	opt2	"Vous sortez de la pièce.",
	pick2	page_12;

! --------------------------------- The End HOURRA FIN DE TRADUCTIOOOOONNNNN-----------------------------------